From 7d5759aa4429c626e66f65e8e0807a999d324e6f Mon Sep 17 00:00:00 2001
From: Richard Purdie <rpurdie@linux.intel.com>
Date: Tue, 14 Apr 2009 12:50:03 +0100
Subject: mesa: Upgrade 7.2 -> 7.4

---
 meta/packages/mesa/mesa-dri_7.4.bb | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 meta/packages/mesa/mesa-dri_7.4.bb

(limited to 'meta/packages/mesa/mesa-dri_7.4.bb')

diff --git a/meta/packages/mesa/mesa-dri_7.4.bb b/meta/packages/mesa/mesa-dri_7.4.bb
new file mode 100644
index 000000000..43e4cb552
--- /dev/null
+++ b/meta/packages/mesa/mesa-dri_7.4.bb
@@ -0,0 +1,37 @@
+include mesa-common.inc
+
+PROTO_DEPS = "xf86driproto glproto dri2proto"
+LIB_DEPS = "libdrm virtual/libx11 libxext libxxf86vm libxdamage libxfixes expat"
+
+DEPENDS = "${PROTO_DEPS}  ${LIB_DEPS}"
+
+PR = "r6"
+
+# most of our targets do not have DRI so will use mesa-xlib
+DEFAULT_PREFERENCE = "-1"
+
+# Netbooks have DRI support so use mesa-dri by default
+DEFAULT_PREFERENCE_netbook = "1"
+
+PACKAGES =+ "${PN}-xprogs"
+PACKAGES_DYNAMIC = "mesa-dri-driver-*"
+
+FILES_${PN}-dbg += "${libdir}/dri/.debug/*"
+FILES_${PN}-xprogs = "${bindir}/glxdemo ${bindir}/glxgears ${bindir}/glxheads ${bindir}/glxinfo"
+
+EXTRA_OECONF += "--with-driver=dri"
+
+do_install_append () {
+    install -d ${D}/usr/bin
+    install -m 0755 ${S}/progs/xdemos/{glxdemo,glxgears,glxheads,glxinfo} ${D}/usr/bin/
+}
+
+python populate_packages_prepend() {
+	import os.path
+
+	dri_drivers_root = os.path.join(bb.data.getVar('libdir', d, 1), "dri")
+
+	do_split_packages(d, dri_drivers_root, '^(.*)_dri\.so$', 'mesa-dri-driver-%s', 'Mesa %s DRI driver', extra_depends='')
+}
+
+COMPATIBLE_HOST = '(i.86.*-linux)'
-- 
cgit v1.2.3