From 36bc4592f4f0e4b4afaba6a0eba21ee9d4ffcfb1 Mon Sep 17 00:00:00 2001
From: Dongxiao Xu <dongxiao.xu@intel.com>
Date: Wed, 21 Jul 2010 10:58:28 +0800
Subject: opkg: Upgraded to version 0.1.8

Use stable release as default recipe.
Remove logfix.patch since the logic is already in latest version package
Also fix the metadata

Signed-off-by: Dongxiao Xu <dongxiao.xu@intel.com>
---
 meta/packages/opkg/opkg_0.1.8.bb | 53 ++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)
 create mode 100644 meta/packages/opkg/opkg_0.1.8.bb

(limited to 'meta/packages/opkg/opkg_0.1.8.bb')

diff --git a/meta/packages/opkg/opkg_0.1.8.bb b/meta/packages/opkg/opkg_0.1.8.bb
new file mode 100644
index 000000000..dcd6fb62e
--- /dev/null
+++ b/meta/packages/opkg/opkg_0.1.8.bb
@@ -0,0 +1,53 @@
+require opkg.inc
+
+PROVIDES += "virtual/update-alternatives"
+RPROVIDES_update-alternatives-cworth += "update-alternatives"
+RCONFLICTS_update-alternatives-cworth = "update-alternatives-dpkg"
+RDEPENDS_${PN} = "${VIRTUAL-RUNTIME_update-alternatives} opkg-config-base"
+RDEPENDS_${PN}_virtclass-native = ""
+RDEPENDS_${PN}_virtclass-nativesdk = ""
+PACKAGE_ARCH_update-alternatives-cworth = "all"
+
+SRC_URI = "http://opkg.googlecode.com/files/opkg-${PV}.tar.gz \
+           file://opkg_unarchive.patch \
+           file://add_vercmp.patch \
+           file://headerfix.patch"
+
+PR = "r0"
+
+PACKAGES =+ "libopkg-dev libopkg update-alternatives-cworth"
+
+FILES_update-alternatives-cworth = "${bindir}/update-alternatives"
+FILES_libopkg-dev = "${libdir}/*.a ${libdir}/*.la ${libdir}/*.so"
+FILES_libopkg = "${libdir}/*.so.* ${libdir}/opkg/"
+
+# We need to create the lock directory
+do_install_append() {
+	install -d ${D}${libdir}/opkg
+}
+
+# Define a variable to allow distros to run configure earlier.
+# (for example, to enable loading of ethernet kernel modules before networking starts)
+OPKG_INIT_POSITION = "98"
+OPKG_INIT_POSITION_slugos = "41"
+
+pkg_postinst_${PN} () {
+#!/bin/sh
+if [ "x$D" != "x" ]; then
+	install -d ${IMAGE_ROOTFS}/${sysconfdir}/rcS.d
+	# this happens at S98 where our good 'ole packages script used to run
+	echo "#!/bin/sh
+opkg-cl configure
+rm -f /${sysconfdir}/rcS.d/S${OPKG_INIT_POSITION}configure
+" > $D${sysconfdir}/rcS.d/S${OPKG_INIT_POSITION}configure
+	chmod 0755 $D${sysconfdir}/rcS.d/S${OPKG_INIT_POSITION}configure
+fi
+
+update-alternatives --install ${bindir}/opkg opkg ${bindir}/opkg-cl 100
+}
+
+pkg_postrm_${PN} () {
+#!/bin/sh
+update-alternatives --remove opkg ${bindir}/opkg-cl
+}
+
-- 
cgit v1.2.3