From 63fbf7dffb07c9adc3e4fbb504dcb81ea335e859 Mon Sep 17 00:00:00 2001
From: Saul Wold <sgw@linux.intel.com>
Date: Tue, 15 Nov 2011 12:58:42 -0800
Subject: gnu-config: Create 2011111 release

Use a yoctoproject.org based tarball since gnu-config is required very
early on in the native build process, we do not want to rely on git, which
can cause a circular dependency issue.

Signed-off-by: Saul Wold <sgw@linux.intel.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
---
 .../gnu-config/gnu-config_20111111.bb              | 41 ++++++++++++++++++++++
 1 file changed, 41 insertions(+)
 create mode 100644 meta/recipes-devtools/gnu-config/gnu-config_20111111.bb

(limited to 'meta/recipes-devtools/gnu-config')

diff --git a/meta/recipes-devtools/gnu-config/gnu-config_20111111.bb b/meta/recipes-devtools/gnu-config/gnu-config_20111111.bb
new file mode 100644
index 000000000..27400c617
--- /dev/null
+++ b/meta/recipes-devtools/gnu-config/gnu-config_20111111.bb
@@ -0,0 +1,41 @@
+SUMMARY = "gnu-configize"
+DESCRIPTION = "Tool that installs the GNU config.guess / config.sub into a directory tree"
+SECTION = "devel"
+LICENSE = "GPLv2"
+LIC_FILES_CHKSUM = "file://config.guess;endline=39;md5=a3669d051b3a8408d69751e53b2e1cc1"
+
+DEPENDS_virtclass-native = "perl-native-runtime"
+
+INHIBIT_DEFAULT_DEPS = "1"
+
+PR = "r0"
+
+SRC_URI = "http://downloads.yoctoproject.org/releases/gnu-config/gnu-config-yocto-${PV}.tgz \
+	   file://config-guess-uclibc.patch \
+           file://gnu-configize.in"
+
+SRC_URI[md5sum] = "30be385c919a25cd9522205ef49e5328"
+SRC_URI[sha256sum] = "0750afa8d8ee988b6ead1c2d02b565597f809e2e3ad14886ed7803d3bbc8b0cd"
+
+do_compile() {
+	:
+}
+
+do_install () {
+	install -d ${D}${datadir}/gnu-config \
+		   ${D}${bindir}
+	cat ${WORKDIR}/gnu-configize.in | \
+		sed -e 's,@gnu-configdir@,${datadir}/gnu-config,g' \
+		    -e 's,@autom4te_perllibdir@,${datadir}/autoconf,g' > ${D}${bindir}/gnu-configize
+	# In the native case we want the system perl as perl-native can't have built yet
+	if [ "${BUILD_ARCH}" != "${TARGET_ARCH}" ]; then
+		sed -i -e 's,/usr/bin/env,${bindir}/env,g' ${D}${bindir}/gnu-configize
+	fi
+	chmod 755 ${D}${bindir}/gnu-configize
+	install -m 0644 config.guess config.sub ${D}${datadir}/gnu-config/
+}
+
+PACKAGES = "${PN}"
+FILES_${PN} = "${bindir} ${datadir}/gnu-config"
+
+BBCLASSEXTEND = "native"
-- 
cgit v1.2.3