From 4b46c1f6e891b1ddd5968536440b888661fade3e Mon Sep 17 00:00:00 2001
From: Richard Purdie <richard@openedhand.com>
Date: Wed, 31 Aug 2005 10:45:47 +0000
Subject: Initial population

git-svn-id: https://svn.o-hand.com/repos/poky@1 311d38ba-8fff-0310-9ca6-ca027cbcb966
---
 .../packages/wireless-tools/wireless-tools_27.bb   | 44 ++++++++++++++++++++++
 1 file changed, 44 insertions(+)
 create mode 100644 openembedded/packages/wireless-tools/wireless-tools_27.bb

(limited to 'openembedded/packages/wireless-tools/wireless-tools_27.bb')

diff --git a/openembedded/packages/wireless-tools/wireless-tools_27.bb b/openembedded/packages/wireless-tools/wireless-tools_27.bb
new file mode 100644
index 000000000..e40c788e9
--- /dev/null
+++ b/openembedded/packages/wireless-tools/wireless-tools_27.bb
@@ -0,0 +1,44 @@
+DESCRIPTION = "Tools for the Linux Standard Wireless Extension Subsystem"
+HOMEPAGE = "http://www.hpl.hp.com/personal/Jean_Tourrilhes/Linux/Tools.html"
+SECTION = "base"
+PRIORITY = "optional"
+#DEPENDS = "virtual/kernel"
+MAINTAINER = "Michael 'Mickey' Lauer <mickey@Vanille.de>"
+LICENSE = "GPL"
+PR = "r1"
+
+SRC_URI = "http://pcmcia-cs.sourceforge.net/ftp/contrib/wireless_tools.${PV}.tar.gz \
+	   file://man.patch;patch=1 \
+	   file://fixheaders.patch;patch=1 \
+	   file://wireless-tools.if-pre-up"
+S = "${WORKDIR}/wireless_tools.${PV}"
+
+CFLAGS =+ "-I${S}"
+EXTRA_OEMAKE = "-e 'BUILD_SHARED=y' \
+		'INSTALL_DIR=${D}${base_sbindir}' \
+		'INSTALL_LIB=${D}${libdir}' \
+		'INSTALL_INC=${D}${includedir}' \
+		'INSTALL_MAN=${D}${mandir}'"
+
+do_compile() {
+	oe_runmake all libiw.a
+}
+
+do_stage () {
+	install -m 0644 wireless.h ${STAGING_INCDIR}/
+	install -m 0644 iwlib.h ${STAGING_INCDIR}/
+	oe_libinstall -a -so libiw ${STAGING_LIBDIR}/
+}
+
+do_install() {
+	oe_runmake PREFIX=${D} install install-static
+	install -d ${D}${sysconfdir}/network/if-pre-up.d
+	install ${WORKDIR}/wireless-tools.if-pre-up ${D}${sysconfdir}/network/if-pre-up.d/wireless-tools
+}
+
+PACKAGES = "libiw libiw-dev libiw-doc ${PN} ${PN}-doc"
+FILES_libiw = "${libdir}/*.so.*"
+FILES_libiw-dev = "${libdir}/*.a ${libdir}/*.so ${includedir}"
+FILES_libiw-doc = "${mandir}/man7"
+FILES_${PN} = "${bindir} ${sbindir} ${base_sbindir} ${base_bindir} ${sysconfdir}/network"
+FILES_${PN}-doc = "${mandir}/man8"
-- 
cgit v1.2.3