function(kicad_generate_header)
    set(options IN_SOURCE)
    set(oneValueArgs OUTPUT NET REF OUTPUT_DIR)

    cmake_parse_arguments(kicad_gen "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

    if (NOT kicad_gen_OUTPUT)
        message(FATAL_ERROR "OUTPUT is required")
    endif ()
    set(output "${kicad_gen_OUTPUT}")

    if (NOT kicad_gen_NET)
        message(FATAL_ERROR "NET is required")
    endif ()
    set(NET "${CMAKE_CURRENT_SOURCE_DIR}/${kicad_gen_NET}")

    if (NOT kicad_gen_REF)
        message(FATAL_ERROR "REF is required")
    endif ()
    set(REF "${kicad_gen_REF}")

    if (kicad_gen_OUTPUT_DIR)
        if (kicad_gen_IN_SOURCE)
            message(FATAL_ERROR "IN_SOURCE can't be used if OUTPUT_DIR is used")
        endif ()

        set(output_dir "${kicad_gen_OUTPUT_DIR}")
    else ()
        if (kicad_gen_IN_SOURCE)
            set(output_dir "${CMAKE_CURRENT_SOURCE_DIR}")
        else ()
            set(output_dir "${CMAKE_CURRENT_BINARY_DIR}")
        endif ()
    endif ()

    set(output_file "${output_dir}/${output}")

    add_custom_command(OUTPUT "${output_file}"
        COMMAND generate-header -n ${NET} -r ${REF} -o ${output_file}
        MAIN_DEPENDENCY ${NET}
        DEPENDS kicad_utils
        COMMENT "Generating ${output}")
endfunction()