From 5a9cdd3cc89507d4d74f8bded56ce5e037b3b56e Mon Sep 17 00:00:00 2001
From: Trygve Laugstøl <trygvis@inamo.no>
Date: Fri, 23 Feb 2024 07:08:18 +0100
Subject: wip

---
 learn-you-some-erlang/my_server.erl | 42 +++++++++++++++++++++++++++++++++++++
 1 file changed, 42 insertions(+)
 create mode 100644 learn-you-some-erlang/my_server.erl

(limited to 'learn-you-some-erlang/my_server.erl')

diff --git a/learn-you-some-erlang/my_server.erl b/learn-you-some-erlang/my_server.erl
new file mode 100644
index 0000000..ed83a7a
--- /dev/null
+++ b/learn-you-some-erlang/my_server.erl
@@ -0,0 +1,42 @@
+-module(my_server).
+-export([start/2, start_link/2, call/2, cast/2, reply/2]).
+
+%%% Public API
+start(Module, InitialState) ->
+    spawn(fun() -> init(Module, InitialState) end).
+
+start_link(Module, InitialState) ->
+    spawn_link(fun() -> init(Module, InitialState) end).
+
+call(Pid, Msg) ->
+    Ref = erlang:monitor(process, Pid),
+    Pid ! {sync, self(), Ref, Msg},
+    receive
+        {Ref, Reply} ->
+            erlang:demonitor(Ref, [flush]),
+            Reply;
+        {'DOWN', Ref, process, Pid, Reason} ->
+            erlang:error(Reason)
+    after 5000 ->
+        erlang:error(timeout)
+    end.
+
+cast(Pid, Msg) ->
+    Pid ! {async, Msg},
+    ok.
+
+reply({Pid, Ref}, Reply) ->
+    Pid ! {Ref, Reply}.
+
+%%% Private stuff
+init(Module, InitialState) ->
+    loop(Module, Module:init(InitialState)).
+
+loop(Module, State) ->
+    receive
+        {async, Msg} ->
+             loop(Module, Module:handle_cast(Msg, State));
+        {sync, Pid, Ref, Msg} ->
+             loop(Module, Module:handle_call(Msg, {Pid, Ref}, State))
+    end.
+
-- 
cgit v1.2.3