meta-moblin: rename images and tasks from poky-* to moblin-*

18 files changed, 542 insertions, 0 deletions

diff --git a/meta-moblin/classes/moblin-image.bbclass b/meta-moblin/classes/moblin-image.bbclass
new file mode 100644
index 000000000..aff89bcef
--- /dev/null
+++ b/meta-moblin/classes/moblin-image.bbclass
@@ -0,0 +1,98 @@
+# Common for Moblin images
+#
+# Copyright (C) 2007 OpenedHand LTD
+
+# IMAGE_FEATURES control content of images built with Poky.
+# 
+# By default we install task-moblin-boot and task-base packages - this gives us
+# working (console only) rootfs.
+#
+# Available IMAGE_FEATURES:
+#
+# - apps-console-core
+# - x11-base            - X11 server + minimal desktop	
+# - x11-sato            - OpenedHand Sato environment
+# - x11-netbook         - Metacity based environment for netbooks
+# - apps-x11-core       - X Terminal, file manager, file editor
+# - apps-x11-games
+# - apps-x11-pimlico    - OpenedHand Pimlico apps
+# - tools-sdk           - SDK
+# - tools-debug         - debugging tools
+# - tools-profile       - profiling tools
+# - tools-testapps      - tools usable to make some device tests
+# - nfs-server          - NFS server (exports / over NFS to everybody)
+# - dev-pkgs            - development packages
+# - dbg-pkgs            - debug packages
+#
+
+MOBLIN_BASE_INSTALL = '\
+    task-moblin-boot \
+    task-base-extended \
+    ${@base_contains("IMAGE_FEATURES", "dbg-pkgs", "task-moblin-boot-dbg task-base-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", "dev-pkgs", "task-moblin-boot-dev task-base-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "apps-console-core", "task-moblin-apps-console", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["apps-console-core", "dbg-pkgs"], "task-moblin-apps-console-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["apps-console-core", "dev-pkgs"], "task-moblin-apps-console-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "x11-base", "task-moblin-x11-base", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["x11-base", "dbg-pkgs"], "task-moblin-x11-base-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["x11-base", "dev-pkgs"], "task-moblin-x11-base-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "x11-sato", "task-moblin-x11-sato", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["x11-sato", "dbg-pkgs"], "task-moblin-x11-sato-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["x11-sato", "dev-pkgs"], "task-moblin-x11-sato-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "x11-netbook", "task-moblin-x11-netbook", "", d)} \
+    ${@base_contains("IMAGE_FEATURES", ["x11-netbook", "dbg-pkgs"], "task-moblin-x11-netbook-dbg", "", d)} \
+    ${@base_contains("IMAGE_FEATURES", ["x11-netbook", "dev-pkgs"], "task-moblin-x11-netbook-dev", "", d)} \
+    ${@base_contains("IMAGE_FEATURES", "apps-x11-core", "task-moblin-apps-x11-core", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["apps-x11-core", "dbg-pkgs"], "task-moblin-apps-x11-core-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["apps-x11-core", "dev-pkgs"], "task-moblin-apps-x11-core-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "apps-x11-games", "task-moblin-apps-x11-games", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["apps-x11-games", "dbg-pkgs"], "task-moblin-apps-x11-games-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["apps-x11-games", "dev-pkgs"], "task-moblin-apps-x11-games-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "apps-x11-pimlico", "task-moblin-apps-x11-pimlico", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["apps-x11-pimlico", "dbg-pkgs"], "task-moblin-apps-x11-pimlico-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["apps-x11-pimlico", "dev-pkgs"], "task-moblin-apps-x11-pimlico-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "tools-debug", "task-moblin-tools-debug", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["tools-debug", "dbg-pkgs"], "task-moblin-tools-debug-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["tools-debug", "dev-pkgs"], "task-moblin-tools-debug-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "tools-profile", "task-moblin-tools-profile", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["tools-profile", "dbg-pkgs"], "task-moblin-tools-profile-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["tools-profile", "dev-pkgs"], "task-moblin-tools-profile-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "tools-testapps", "task-moblin-tools-testapps", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["tools-testapps", "dbg-pkgs"], "task-moblin-tools-testapps-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["tools-testapps", "dev-pkgs"], "task-moblin-tools-testapps-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "tools-sdk", "task-moblin-sdk task-moblin-standalone-sdk-target", "",d)} \    
+    ${@base_contains("IMAGE_FEATURES", ["tools-sdk", "dbg-pkgs"], "task-moblin-sdk-dbg", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["tools-sdk", "dev-pkgs"], "task-moblin-sdk-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "nfs-server", "task-moblin-nfs-server", "",d)} \
+    ${@base_contains("IMAGE_FEATURES", ["nfs-server", "dbg-pkgs"], "task-moblin-nfs-server-dbg", "",d)} \
+
+    ${@base_contains("IMAGE_FEATURES", ["nfs-server", "dev-pkgs"], "task-moblin-nfs-server-dev", "",d)} \
+    \
+    ${@base_contains("IMAGE_FEATURES", "package-management", "${ROOTFS_PKGMANAGE}", "",d)} \
+    ${MOBLIN_EXTRA_INSTALL} \
+    '
+
+MOBLIN_EXTRA_INSTALL ?= ""
+
+IMAGE_INSTALL ?= "${MOBLIN_BASE_INSTALL}"
+
+X11_IMAGE_FEATURES  = "x11-base apps-x11-core package-management"
+ENHANCED_IMAGE_FEATURES = "${X11_IMAGE_FEATURES} apps-x11-games apps-x11-pimlico package-management"
+SATO_IMAGE_FEATURES = "${ENHANCED_IMAGE_FEATURES} apps-x11-sato"
+NETBOOK_IMAGE_FEATURES = "${ENHANCED_IMAGE_FEATURES} apps-x11-netbook"
+
+inherit image
+
+# Create /etc/timestamp during image construction to give a reasonably sane default time setting
+ROOTFS_POSTPROCESS_COMMAND += "rootfs_update_timestamp"
diff --git a/meta-moblin/packages/images/moblin-image-live.bb b/meta-moblin/packages/images/moblin-image-live.bb
new file mode 100644
index 000000000..ff12fd407
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-live.bb
@@ -0,0 +1,9 @@
+DESCRIPTION = "Netbook Bootable Live Image"
+
+require moblin-image-live.inc
+
+LABELS += "boot install"
+
+ROOTFS = "${DEPLOY_DIR_IMAGE}/moblin-image-netbook-${MACHINE}.ext3"
+
+do_bootimg[depends] += "moblin-image-netbook:do_rootfs"
diff --git a/meta-moblin/packages/images/moblin-image-live.inc b/meta-moblin/packages/images/moblin-image-live.inc
new file mode 100644
index 000000000..2dd9a8917
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-live.inc
@@ -0,0 +1,18 @@
+AUTO_SYSLINUXCFG = "1"
+INITRD = "${DEPLOY_DIR_IMAGE}/moblin-image-minimal-initramfs-${MACHINE}.cpio.gz"
+APPEND += "root=/dev/ram0 "
+TIMEOUT = "10"
+
+EXCLUDE_FROM_WORLD = "1"
+
+do_bootimg[depends] += "moblin-image-minimal-initramfs:do_rootfs"
+
+inherit bootimg
+
+do_bootimg_prepend () {
+	import bb
+	fstypes = bb.data.getVar('IMAGE_FSTYPES', d, True)
+	if 'ext3' not in fstypes:
+		bb.msg.fatal(bb.msg.domain.Build, "ext3 not in IMAGE_FSTYPES")
+}
+
diff --git a/meta-moblin/packages/images/moblin-image-minimal-initramfs.bb b/meta-moblin/packages/images/moblin-image-minimal-initramfs.bb
new file mode 100644
index 000000000..1626a4067
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-minimal-initramfs.bb
@@ -0,0 +1,8 @@
+# Simple initramfs image. Mostly used for live images.
+
+IMAGE_INSTALL = "initramfs-live-boot initramfs-live-install busybox udev"
+
+export IMAGE_BASENAME = "moblin-image-minimal-initramfs"
+IMAGE_LINGUAS = ""
+
+inherit moblin-image
diff --git a/meta-moblin/packages/images/moblin-image-minimal-live.bb b/meta-moblin/packages/images/moblin-image-minimal-live.bb
new file mode 100644
index 000000000..83dab3ecc
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-minimal-live.bb
@@ -0,0 +1,9 @@
+DESCRIPTION = "Minimal Bootable Live Image"
+
+require moblin-image-live.inc
+
+LABELS += "boot install"
+
+ROOTFS = "${DEPLOY_DIR_IMAGE}/moblin-image-minimal-${MACHINE}.ext3"
+
+do_bootimg[depends] += "moblin-image-minimal:do_rootfs"
diff --git a/meta-moblin/packages/images/moblin-image-netbook.bb b/meta-moblin/packages/images/moblin-image-netbook.bb
new file mode 100644
index 000000000..a573dbe83
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-netbook.bb
@@ -0,0 +1,7 @@
+#
+# Copyright (C) 2007 OpenedHand Ltd.
+#
+
+IMAGE_FEATURES += "apps-console-core ${NETBOOK_IMAGE_FEATURES}"
+
+inherit moblin-image
diff --git a/meta-moblin/packages/images/moblin-image-sato-live.bb b/meta-moblin/packages/images/moblin-image-sato-live.bb
new file mode 100644
index 000000000..81c07b7e5
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-sato-live.bb
@@ -0,0 +1,9 @@
+DESCRIPTION = "Sato Bootable Live Image"
+
+require moblin-image-live.inc
+
+LABELS += "boot install"
+
+ROOTFS = "${DEPLOY_DIR_IMAGE}/moblin-image-sato-${MACHINE}.ext3"
+
+do_bootimg[depends] += "moblin-image-sato:do_rootfs"
diff --git a/meta-moblin/packages/images/moblin-image-sato.bb b/meta-moblin/packages/images/moblin-image-sato.bb
new file mode 100644
index 000000000..61f97334f
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-sato.bb
@@ -0,0 +1,7 @@
+#
+# Copyright (C) 2007 OpenedHand Ltd.
+#
+
+IMAGE_FEATURES += "apps-console-core ${SATO_IMAGE_FEATURES}"
+
+inherit moblin-image
diff --git a/meta-moblin/packages/images/moblin-image-sdk-live.bb b/meta-moblin/packages/images/moblin-image-sdk-live.bb
new file mode 100644
index 000000000..84cf10753
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-sdk-live.bb
@@ -0,0 +1,9 @@
+DESCRIPTION = "Bootable Live SDK Image"
+
+require moblin-image-live.inc
+
+LABELS += "boot install"
+
+ROOTFS = "${DEPLOY_DIR_IMAGE}/moblin-image-sdk-${MACHINE}.ext3"
+
+do_bootimg[depends] += "moblin-image-sdk:do_rootfs"
diff --git a/meta-moblin/packages/images/moblin-image-sdk.bb b/meta-moblin/packages/images/moblin-image-sdk.bb
new file mode 100644
index 000000000..0ec00f257
--- /dev/null
+++ b/meta-moblin/packages/images/moblin-image-sdk.bb
@@ -0,0 +1,7 @@
+#
+# Copyright (C) 2007 OpenedHand Ltd.
+#
+
+IMAGE_FEATURES += "apps-console-core ${SATO_IMAGE_FEATURES} tools-debug tools-profile tools-sdk dev-pkgs dbg-pkgs"
+
+inherit moblin-image
diff --git a/meta-moblin/packages/tasks/task-moblin-boot.bb b/meta-moblin/packages/tasks/task-moblin-boot.bb
new file mode 100644
index 000000000..a5b78fcf8
--- /dev/null
+++ b/meta-moblin/packages/tasks/task-moblin-boot.bb
@@ -0,0 +1,32 @@
+#
+# Copyright (C) 2007 OpenedHand Ltd.
+#
+
+DESCRIPTION = "Task for Moblin - minimal bootable image"
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+DEPENDS = "virtual/kernel"
+ALLOW_EMPTY = "1"
+PR = "r7"
+
+#
+# Set by the machine configuration with packages essential for device bootup
+#
+MACHINE_ESSENTIAL_EXTRA_RDEPENDS ?= ""
+MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS ?= ""
+
+RDEPENDS_task-moblin-boot = "\
+    base-files \
+    base-passwd \
+    busybox \
+    initscripts \
+    ${@base_contains("MACHINE_FEATURES", "keyboard", "keymaps", "", d)} \
+    modutils-initscripts \
+    netbase \
+    sysvinit \
+    tinylogin \
+    udev \
+    ${VIRTUAL-RUNTIME_update-alternatives} \
+    ${MACHINE_ESSENTIAL_EXTRA_RDEPENDS}"
+
+RRECOMMENDS_task-moblin-boot = "\
+    ${MACHINE_ESSENTIAL_EXTRA_RRECOMMENDS}"
diff --git a/meta-moblin/packages/tasks/task-moblin-sdk.bb b/meta-moblin/packages/tasks/task-moblin-sdk.bb
new file mode 100644
index 000000000..84bb71a84
--- /dev/null
+++ b/meta-moblin/packages/tasks/task-moblin-sdk.bb
@@ -0,0 +1,83 @@
+#
+# Copyright (C) 2007 OpenedHand Ltd.
+#
+
+DESCRIPTON = "Software Development Tasks for Moblin"
+DEPENDS = "task-moblin"
+PR = "r5"
+
+ALLOW_EMPTY = "1"
+#PACKAGEFUNCS =+ 'generate_sdk_pkgs'
+
+PACKAGES = "\
+    task-moblin-sdk \
+    task-moblin-sdk-dbg \
+    task-moblin-sdk-dev"
+
+RDEPENDS_task-moblin-sdk = "\
+    autoconf \
+    automake \
+    binutils \
+    binutils-symlinks \
+    coreutils \
+    cpp \
+    cpp-symlinks \
+    diffutils \
+    gcc \
+    gcc-symlinks \
+    g++ \
+    g++-symlinks \
+    gettext \
+    make \
+    intltool \
+    libstdc++ \
+    libstdc++-dev \
+    libtool \
+    perl-module-re \
+    perl-module-text-wrap \
+    pkgconfig \
+    findutils \
+    quilt \
+    less \
+    distcc"
+
+#python generate_sdk_pkgs () {
+#    moblin_pkgs = read_pkgdata('task-moblin', d)['PACKAGES']
+#    pkgs = bb.data.getVar('PACKAGES', d, 1).split()
+#    for pkg in moblin_pkgs.split():
+#        newpkg = pkg.replace('task-moblin', 'task-moblin-sdk')
+#
+#        # for each of the task packages, add a corresponding sdk task
+#        pkgs.append(newpkg)
+#
+#        # for each sdk task, take the rdepends of the non-sdk task, and turn
+#        # that into rrecommends upon the -dev versions of those, not unlike
+#        # the package depchain code
+#        spkgdata = read_subpkgdata(pkg, d)
+#
+#        rdepends = explode_deps(spkgdata.get('RDEPENDS_%s' % pkg) or '')
+#        rreclist = []
+#
+#        for depend in rdepends:
+#            split_depend = depend.split(' (')
+#            name = split_depend[0].strip()
+#            if packaged('%s-dev' % name, d):
+#                rreclist.append('%s-dev' % name)
+#            else:
+#                deppkgdata = read_subpkgdata(name, d)
+#                rdepends2 = explode_deps(deppkgdata.get('RDEPENDS_%s' % name) or '')
+#                for depend in rdepends2:
+#                    split_depend = depend.split(' (')
+#                    name = split_depend[0].strip()
+#                    if packaged('%s-dev' % name, d):
+#                        rreclist.append('%s-dev' % name)
+#
+#            oldrrec = bb.data.getVar('RRECOMMENDS_%s' % newpkg, d) or ''
+#            bb.data.setVar('RRECOMMENDS_%s' % newpkg, oldrrec + ' ' + ' '.join(rreclist), d)
+#            # bb.note('RRECOMMENDS_%s = "%s"' % (newpkg, bb.data.getVar('RRECOMMENDS_%s' % newpkg, d)))
+#
+#    # bb.note('pkgs is %s' % pkgs)
+#    bb.data.setVar('PACKAGES', ' '.join(pkgs), d)
+#}
+#
+#PACKAGES_DYNAMIC = "task-moblin-sdk-*"
diff --git a/meta-moblin/packages/tasks/task-moblin-standalone-sdk-target.bb b/meta-moblin/packages/tasks/task-moblin-standalone-sdk-target.bb
new file mode 100644
index 000000000..e9384f5ec
--- /dev/null
+++ b/meta-moblin/packages/tasks/task-moblin-standalone-sdk-target.bb
@@ -0,0 +1,40 @@
+DESCRIPTION = "Target packages for the standalone SDK"
+PR = "r4"
+LICENSE = "MIT"
+ALLOW_EMPTY = "1"
+
+PACKAGES = "${PN} ${PN}-dbg"
+
+RDEPENDS_${PN} = "\
+    libgcc \
+    libstdc++ \
+    "
+
+GLIBC_DEPENDENCIES = "\
+    libsegfault \
+    glibc \
+    glibc-dbg \
+    glibc-dev \
+    glibc-utils \
+    glibc-thread-db \
+    glibc-localedata-i18n \
+    glibc-gconv-ibm850 \
+    glibc-gconv-cp1252 \
+    glibc-gconv-iso8859-1 \
+    glibc-gconv-iso8859-15 \
+    locale-base-en-gb \
+    "
+
+RDEPENDS_${PN}_append_linux = "${GLIBC_DEPENDENCIES}"
+RDEPENDS_${PN}_append_linux-gnueabi = "${GLIBC_DEPENDENCIES}"
+
+UCLIBC_DEPENDENCIES = "\
+    uclibc \
+    uclibc-dbg \
+    uclibc-dev \
+    uclibc-thread-db \
+    "
+
+RDEPENDS_${PN}_append_linux-uclibc = "${UCLIBC_DEPENDENCIES}"
+RDEPENDS_${PN}_append_linux-uclibcgnueabi = "${UCLIBC_DEPENDENCIES}"
+
diff --git a/meta-moblin/packages/tasks/task-moblin-x11-netbook.bb b/meta-moblin/packages/tasks/task-moblin-x11-netbook.bb
new file mode 100644
index 000000000..90ee0d1ac
--- /dev/null
+++ b/meta-moblin/packages/tasks/task-moblin-x11-netbook.bb
@@ -0,0 +1,28 @@
+#
+# Copyright (C) 2008 Intel.
+#
+
+DESCRIPTION = "Netbook Tasks for Moblin"
+PR = "r0"
+
+PACKAGES = "\
+    task-moblin-x11-netbook \
+    task-moblin-x11-netbook-dbg \
+    task-moblin-x11-netbook-dev \
+    "
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+ALLOW_EMPTY = "1"
+
+NETWORK_MANAGER ?= "networkmanager-applet"
+RDEPENDS_task-moblin-x11-netbook = "\
+    metacity-clutter \
+    matchbox-desktop \
+    matchbox-session-netbook \
+    matchbox-config-gtk \
+    xcursor-transparent-theme \
+    sato-icon-theme \
+    settings-daemon \
+    gtk-sato-engine \
+    ${NETWORK_MANAGER}"
diff --git a/meta-moblin/packages/tasks/task-moblin-x11-sato.bb b/meta-moblin/packages/tasks/task-moblin-x11-sato.bb
new file mode 100644
index 000000000..6ae3bc07c
--- /dev/null
+++ b/meta-moblin/packages/tasks/task-moblin-x11-sato.bb
@@ -0,0 +1,29 @@
+#
+# Copyright (C) 2007-2008 OpenedHand Ltd.
+#
+
+DESCRIPTION = "Sato Tasks for Moblin"
+PR = "r29"
+
+PACKAGES = "\
+    task-moblin-x11-sato \
+    task-moblin-x11-sato-dbg \
+    task-moblin-x11-sato-dev \
+    "
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+ALLOW_EMPTY = "1"
+
+NETWORK_MANAGER ?= "networkmanager-applet"
+RDEPENDS_task-moblin-x11-sato = "\
+    matchbox-desktop \
+    matchbox-session-sato \
+    matchbox-keyboard \
+    matchbox-stroke \
+    matchbox-config-gtk \
+    xcursor-transparent-theme \
+    sato-icon-theme \
+    settings-daemon \
+    gtk-sato-engine \
+    ${NETWORK_MANAGER}"
diff --git a/meta-moblin/packages/tasks/task-moblin.bb b/meta-moblin/packages/tasks/task-moblin.bb
new file mode 100644
index 000000000..cb9f0c34c
--- /dev/null
+++ b/meta-moblin/packages/tasks/task-moblin.bb
@@ -0,0 +1,66 @@
+#
+# Copyright (C) 2007-2008 OpenedHand Ltd.
+#
+
+DESCRIPTION = "Tasks for Moblin"
+PR = "r30"
+
+PACKAGES = "\
+    task-moblin-apps-console \
+    task-moblin-apps-console-dbg \
+    task-moblin-apps-console-dev \
+    task-moblin-apps-x11-core \
+    task-moblin-apps-x11-core-dbg \
+    task-moblin-apps-x11-core-dev \
+    task-moblin-apps-x11-games \
+    task-moblin-apps-x11-games-dbg \
+    task-moblin-apps-x11-games-dev \
+    task-moblin-x11-base \
+    task-moblin-x11-base-dbg \
+    task-moblin-x11-base-dev \
+    "
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+XSERVER ?= "xserver-kdrive-fbdev"
+
+ALLOW_EMPTY = "1"
+
+
+RDEPENDS_task-moblin-apps-console = "\
+    avahi-daemon \
+    dropbear \
+    dbus \
+    portmap \
+    psplash"
+
+
+RDEPENDS_task-moblin-x11-base = "\
+    dbus \
+    pointercal \
+    matchbox-wm \
+    matchbox-keyboard \
+    matchbox-keyboard-applet \
+    matchbox-keyboard-im \
+    matchbox-panel-2 \
+    matchbox-desktop \
+    matchbox-session \
+    ${XSERVER} \
+    x11-common \
+    xserver-nodm-init \
+    liberation-fonts \
+    xauth \
+    xhost \
+    xset \
+    xrandr"
+
+
+RDEPENDS_task-moblin-apps-x11-core = "\
+    leafpad \
+    pcmanfm \
+    matchbox-terminal \
+    screenshot"
+
+
+RDEPENDS_task-moblin-apps-x11-games = "\
+    oh-puzzles"
diff --git a/meta-moblin/packages/tasks/tasks-moblin-apps-x11-pimlico.bb b/meta-moblin/packages/tasks/tasks-moblin-apps-x11-pimlico.bb
new file mode 100644
index 000000000..1ab8163fc
--- /dev/null
+++ b/meta-moblin/packages/tasks/tasks-moblin-apps-x11-pimlico.bb
@@ -0,0 +1,26 @@
+#
+# Copyright (C) 2007-2008 OpenedHand Ltd.
+#
+
+DESCRIPTION = "X11 Pimlico Appications List"
+PR = "r27"
+
+PACKAGES = "\
+    task-moblin-apps-x11-pimlico \
+    task-moblin-apps-x11-pimlico-dbg \
+    task-moblin-apps-x11-pimlico-dev \
+    "
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+ALLOW_EMPTY = "1"
+
+WEB = "web-webkit"
+
+RDEPENDS_task-moblin-apps-x11-pimlico = "\
+    eds-dbus \
+    contacts \
+    dates \
+    tasks \
+    gaku \
+    ${WEB}"
diff --git a/meta-moblin/packages/tasks/tasks-moblin-tools.bb b/meta-moblin/packages/tasks/tasks-moblin-tools.bb
new file mode 100644
index 000000000..33dad20d8
--- /dev/null
+++ b/meta-moblin/packages/tasks/tasks-moblin-tools.bb
@@ -0,0 +1,57 @@
+#
+# Copyright (C) 2008 OpenedHand Ltd.
+#
+
+DESCRIPTION = "Tools tasks for Moblin"
+PR = "r1"
+
+PACKAGES = "\
+    task-moblin-tools-debug \
+    task-moblin-tools-debug-dbg \
+    task-moblin-tools-debug-dev \
+    task-moblin-tools-profile \
+    task-moblin-tools-profile-dbg \
+    task-moblin-tools-profile-dev \
+    task-moblin-tools-testapps \
+    task-moblin-tools-testapps-dbg \
+    task-moblin-tools-testapps-dev \
+    "
+
+PACKAGE_ARCH = "${MACHINE_ARCH}"
+
+ALLOW_EMPTY = "1"
+
+RDEPENDS_task-moblin-tools-debug = "\
+    gdb \
+    gdbserver \
+    strace"
+
+RDEPENDS_task-moblin-tools-profile = "\
+    exmap-console \
+    exmap-server \
+    oprofile \
+    oprofileui-server \
+    powertop \
+    lttng-control \
+    lttng-viewer"
+
+RDEPENDS_task-moblin-tools-profile_qemux86 += "valgrind"
+
+RRECOMMENDS_task-moblin-tools-profile = "\
+    kernel-module-oprofile"
+
+RDEPENDS_task-moblin-tools-testapps = "\
+    blktool \
+    tslib-calibrate \
+    tslib-tests \
+    lrzsz \
+    kexec-tools \
+    alsa-utils-amixer \
+    alsa-utils-aplay \
+    owl-video \
+    gst-meta-video \
+    gst-meta-audio \
+    xrestop \
+    xwininfo \
+    xprop \
+    xvideo-tests"