pciutils: upgrade to version 3.1.5

from 3.0.3

changes:
  - rebased patch configure.patch and pcimodules-pciutils.diff
  - fix a bug in parameter order in config that causes invalid
    search path and library version
  - remove unnecessary kernel version reference in configure
  - use DESTDIR mechanism for build and installation
  - pciutils should RDEPENDS on pciutils-ids
  - enable shared library build and package a new package series,
    libpci
  - conceive a new patch to fix shared library build, default build
    would embedd invalid library dependencies
  - add another patch to fix build on arm
  - fix a bug in previous do_install_depends that used invalid
    installation mode
  - symbolic link /usr/sbin/pciutils to /usr/bin, so non-root user
    can use it as well

Signed-off-by: Qing He <qing.he@intel.com>

1 files changed, 56 insertions, 0 deletions

diff --git a/meta/packages/pciutils/pciutils_3.1.5.bb b/meta/packages/pciutils/pciutils_3.1.5.bb
new file mode 100644
index 000000000..73fe1cca6
--- /dev/null
+++ b/meta/packages/pciutils/pciutils_3.1.5.bb
@@ -0,0 +1,56 @@
+DESCRIPTION = 'The PCI Utilities package contains a library for portable access \
+to PCI bus configuration space and several utilities based on this library.'
+DESCRIPTION_pciutils-ids = 'The list of PCI IDs for pciutils'
+HOMEPAGE = "http://atrey.karlin.mff.cuni.cz/~mj/pciutils.shtml"
+SECTION = "console/utils"
+
+LICENSE = "GPLv2+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe"
+DEPENDS = "zlib"
+RDEPENDS_${PN} = "${PN}-ids"
+PR = "r0"
+
+SRC_URI = "ftp://ftp.kernel.org/pub/software/utils/pciutils/pciutils-${PV}.tar.bz2 \
+           file://configure.patch \
+           file://pcimodules-pciutils.diff \
+           file://lib-build-fix.patch \
+           file://guess-fix.patch"
+
+PARALLEL_MAKE = ""
+
+PCI_CONF_FLAG = "ZLIB=yes DNS=yes SHARED=yes"
+
+# see configure.patch
+do_configure () {
+	(
+	  cd lib && \
+	  ${PCI_CONF_FLAG} ./configure ${PV} ${datadir} ${TARGET_OS} ${TARGET_ARCH}
+	)
+}
+
+export PREFIX = "${prefix}"
+export SBINDIR = "${sbindir}"
+export SHAREDIR = "${datadir}"
+export MANDIR = "${mandir}"
+
+EXTRA_OEMAKE += "${PCI_CONF_FLAG}"
+
+# The configure script breaks if the HOST variable is set
+HOST[unexport] = "1"
+
+do_install () {
+	oe_runmake DESTDIR=${D} install install-lib
+
+	install -d ${D}${bindir}
+	ln -s ../sbin/lspci ${D}${bindir}/lspci
+
+	install -d ${D}${datadir}
+	install -m 644 ${S}/pci.ids ${D}${datadir}
+}
+
+PACKAGES =+ "pciutils-ids libpci libpci-dev libpci-dbg"
+FILES_pciutils-ids = "${datadir}/pci.ids*"
+FILES_libpci = "${libdir}/libpci.so.*"
+FILES_libpci-dbg = "${libdir}/.debug"
+FILES_libpci-dev = "${libdir}/libpci.a ${libdir}/libpci.la ${libdir}/libpci.so \
+                    ${includedir}/pci ${libdir}/pkgconfig"