prelink: upgrade from 20061027 to 20100106

This need change to elfutils. elfutils changes are added in separate commit.

Removed the patch arm_eabi.patch, as it is included in the new sources

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>

1 files changed, 45 insertions, 0 deletions

diff --git a/meta/packages/prelink/prelink_20100106.bb b/meta/packages/prelink/prelink_20100106.bb
new file mode 100644
index 000000000..a84aaa267
--- /dev/null
+++ b/meta/packages/prelink/prelink_20100106.bb
@@ -0,0 +1,45 @@
+SECTION = "devel"
+DEPENDS = "elfutils"
+DESCRIPTION = " The prelink package contains a utility which modifies ELF shared libraries \
+and executables, so that far fewer relocations need to be resolved at \
+runtime and thus programs come up faster."
+LICENSE = "GPL"
+PR = "r0"
+
+SRC_URI = "http://people.redhat.com/jakub/prelink/prelink-${PV}.tar.bz2 \
+           file://prelink.conf \
+           file://prelink.cron.daily \
+           file://prelink.default"
+
+TARGET_OS_ORIG := "${TARGET_OS}"
+OVERRIDES_append = ":${TARGET_OS_ORIG}"
+
+S = "${WORKDIR}/prelink"
+
+EXTRA_OECONF = "--disable-64bit"
+
+inherit autotools 
+
+do_install_append () {
+	install -d ${D}${sysconfdir}/cron.daily ${D}${sysconfdir}/default
+	install -m 0644 ${WORKDIR}/prelink.conf ${D}${sysconfdir}/prelink.conf
+	install -m 0644 ${WORKDIR}/prelink.cron.daily ${D}${sysconfdir}/cron.daily/prelink
+	install -m 0644 ${WORKDIR}/prelink.default ${D}${sysconfdir}/default/prelink
+}
+
+pkg_postinst_prelink() {
+#!/bin/sh
+
+if [ "x$D" != "x" ]; then
+  exit 1
+fi
+
+prelink -a
+}
+
+pkg_postrm_prelink() {
+#!/bin/sh
+
+prelink -au
+}
+