udev: upgrade to version 158

older versions are kept untouched for now

changes:
  - udev has diverged a lot, the udev.inc was based on a quite dated
    version, thus doesn't reflect current status of udev, create a
    new include file udev-new.inc to adapt
  - separate libudev{,-dev,-dbg} apart from udev
  - --with-udev-prefix is removed. change ${libexecdir} to
    ${base_libdir}/udev, which is described in INSTALL file.
  - udev.pc is provided in ${datadir}/pkgconfig, since it's used
    to indicate the existence of udev itself instead of development
    headers and libs, pack it in udev instead of udev-dev
  - udev-extras is disabled since we are missing libacl, this also
    means gudev is missing as for now
  - other cleanups, e.g. do_stage, do_install, EXTRA_OEMAKE

todo:
  - udev-extras
  - remove old udev versions
  - rebase udev-145 on udev-new.inc as well

Signed-off-by: Qing He <qing.he@intel.com>

1 files changed, 87 insertions, 0 deletions

diff --git a/meta/packages/udev/udev-new.inc b/meta/packages/udev/udev-new.inc
new file mode 100644
index 000000000..de02b23ee
--- /dev/null
+++ b/meta/packages/udev/udev-new.inc
@@ -0,0 +1,87 @@
+DESCRIPTION = "udev is a daemon which dynamically creates and removes device nodes from \
+/dev/, handles hotplug events and loads drivers at boot time. It replaces \
+the hotplug package and requires a kernel not older than 2.6.12."
+HOMEPAGE = "http://www.kernel.org/pub/linux/utils/kernel/hotplug/udev.html"
+LICENSE = "GPLv2+ & LGPLv2.1+"
+LICENSE_${PN} = "GPLv2+"
+LICENSE_libudev = "LGPLv2.1+"
+#LICENSE_libgudev = "LGPLv2.1+"
+LIC_FILES_CHKSUM = "file://COPYING;md5=751419260aa954499f7abaabaa882bbe \
+                    file://libudev/COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343 \
+                    file://extras/gudev/COPYING;md5=a6f89e2100d9b6cdffcea4f398e37343"
+
+# the following dependency is needed for udev-extras
+#DEPENDS = "libacl glib-2.0 libusb usbutils pciutils linux-libc-headers gperf-native"
+RPROVIDES_${PN} = "hotplug"
+RRECOMMENDS_${PN} += "udev-extraconf udev-cache"
+
+SRC_URI = "http://kernel.org/pub/linux/utils/kernel/hotplug/udev-${PV}.tar.gz \
+           file://run.rules \
+           file://udev.rules \
+           file://devfs-udev.rules \
+           file://links.conf \
+           file://permissions.rules \
+           file://mount.sh \
+           file://network.sh \
+           file://local.rules \
+           file://udev-cache \
+           file://init"
+
+SRC_URI_append_h2200 = " file://50-hostap_cs.rules "
+
+inherit autotools pkgconfig update-rc.d
+
+# udevd/udevadm -> /sbin/, libudev.so.* -> /lib/
+sbindir = "${base_sbindir}"
+libexecdir = "${base_libdir}/udev"
+EXTRA_OECONF = "--disable-extras --disable-introspection --with-rootlibdir=${base_libdir}"
+
+PACKAGES =+ "udev-cache libudev libudev-dev libudev-dbg"
+PACKAGE_ARCH_h2200 = "h2200"
+
+INITSCRIPT_PACKAGES = "udev udev-cache"
+INITSCRIPT_NAME_udev = "udev"
+INITSCRIPT_PARAMS_udev = "start 04 S ."
+INITSCRIPT_NAME_udev-cache = "udev-cache"
+INITSCRIPT_PARAMS_udev-cache = "start 36 S ."
+
+FILES_${PN} += "${libexecdir} ${datadir}/pkgconfig/udev.pc"
+FILES_${PN}-dbg += "${libexecdir}/.debug"
+FILES_${PN}-dev = ""
+FILES_libudev = "${base_libdir}/libudev.so.*"
+FILES_libudev-dbg = "${base_libdir}/.debug/libudev.so.*"
+FILES_libudev-dev = "${includedir}/libudev.h ${libdir}/libudev.so ${libdir}/libudev.la \
+                     ${libdir}/libudev.a ${libdir}/pkgconfig/libudev.pc"
+FILES_udev-cache = "${sysconfdir}/init.d/udev-cache"
+
+
+do_install_append () {
+	install -d ${D}${sysconfdir}/init.d
+	install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/udev
+	install -m 0755 ${WORKDIR}/udev-cache ${D}${sysconfdir}/init.d/udev-cache
+
+	install -d ${D}${sysconfdir}/udev/rules.d/
+
+	install -m 0644 ${WORKDIR}/local.rules         ${D}${sysconfdir}/udev/rules.d/local.rules
+	#install -m 0644 ${WORKDIR}/permissions.rules   ${D}${sysconfdir}/udev/rules.d/permissions.rules
+	#install -m 0644 ${WORKDIR}/run.rules          ${D}${sysconfdir}/udev/rules.d/run.rules
+	#install -m 0644 ${WORKDIR}/udev.rules          ${D}${sysconfdir}/udev/rules.d/udev.rules
+	install -m 0644 ${WORKDIR}/links.conf          ${D}${sysconfdir}/udev/links.conf
+	#if [ "${UDEV_DEVFS_RULES}" = "1" ]; then
+	#	install -m 0644 ${WORKDIR}/devfs-udev.rules ${D}${sysconfdir}/udev/rules.d/devfs-udev.rules
+	#fi
+
+	# Remove some default rules that don't work well on embedded devices
+	#rm ${D}${libexecdir}/rules.d/60-persistent-input.rules
+	#rm ${D}${libexecdir}/rules.d/60-persistent-storage.rules
+	#rm ${D}${libexecdir}/rules.d/60-persistent-storage-tape.rules
+
+	install -d ${D}${sysconfdir}/udev/scripts/
+
+	install -m 0755 ${WORKDIR}/mount.sh ${D}${sysconfdir}/udev/scripts/mount.sh
+	install -m 0755 ${WORKDIR}/network.sh ${D}${sysconfdir}/udev/scripts
+}
+
+do_install_append_h2200() {
+	install -m 0644 ${WORKDIR}/50-hostap_cs.rules         ${D}${sysconfdir}/udev/rules.d/50-hostap_cs.rules
+}