libtool family: upgrade from 2.2.6 to 2.2.10

This upgrades these recipes:
 libtool_2.2.6.bb -> libtool_2.2.10.bb
 libtool-native_2.2.6.bb -> libtool-native_2.2.10.bb
 libtool-cross_2.2.6.bb -> libtool-cross_2.2.10.bb
 libtool-nativesdk_2.2.6.bb -> libtool-nativesdk_2.2.10.bb
    Also fixes build failure caused by having aclocal.m4 built with older version
    of libtool.

Rebased these patches for the newer version sources
 add_dolt.patch
 cross_compile.patch
 dolt.m4

Changed this patch to fix documentation building for non-x86 archs
 prefix.patch

Rebased and changed to fix the building of ncurses recipe:
 trailingslash.patch

Also updated metadata variables like LICENSE & LIC_CHKSUM_FILES

Signed-off-by: Nitin A Kamble <nitin.a.kamble@intel.com>

1 files changed, 33 insertions, 0 deletions

diff --git a/meta/packages/libtool/libtool_2.2.10.bb b/meta/packages/libtool/libtool_2.2.10.bb
new file mode 100644
index 000000000..cca3b1ea4
--- /dev/null
+++ b/meta/packages/libtool/libtool_2.2.10.bb
@@ -0,0 +1,33 @@
+require libtool.inc
+DEPENDS = "libtool-native"
+
+PR = "r0"
+
+PACKAGES =+ "libltdl libltdl-dev libltdl-dbg"
+FILES_${PN} += "${datadir}/aclocal*"
+FILES_libltdl = "${libdir}/libltdl.so.*"
+FILES_libltdl-dev = "${libdir}/libltdl.* ${includedir}/ltdl.h"
+FILES_libltdl-dbg = "${libdir}/.debug/"
+
+inherit autotools
+
+EXTRA_AUTORECONF = "--exclude=libtoolize"
+
+do_compile_prepend () {
+	# Sometimes this file doesn't get rebuilt, force the issue
+	rm -f ${S}/libltdl/config/ltmain.sh
+	make libltdl/config/ltmain.sh
+}
+
+#
+# We want the results of libtool-cross preserved - don't stage anything ourselves.
+#
+SYSROOT_PREPROCESS_FUNCS += "libtool_sysroot_preprocess"
+
+libtool_sysroot_preprocess () {
+	if [ "${PN}" == "libtool" ]; then
+		rm -rf ${SYSROOT_DESTDIR}${STAGING_DIR_TARGET}${bindir}/*
+		rm -rf ${SYSROOT_DESTDIR}${STAGING_DIR_TARGET}${datadir}/aclocal/*
+		rm -rf ${SYSROOT_DESTDIR}${STAGING_DIR_TARGET}${datadir}/libtool/config/*
+	fi
+}